This section provides a tutorial example on how to use the Folder class that represents a file folder of a file system. Folder class is provided in the Scripting Runtime DLL, scrrun.dll.
Folder: A class representing a file folder in a file system. It offers the following
properties and methods:
"Attributes": Property to return the attributes of the folder.
"DateCreated": Property to return the date and time when the folder was created.
"DateLastAccessed": Property to return the date and time when the folder was last accessed.
"DateLastModified": Property to return the date and time when the folder was last modified.
"Drive": Property to return the driver letter of the folder.
"Files": Property to return a read-only collection of "File" objects representing all the files in the folder.
"IsRootFolder": Property to return true if the folder is a root folder.
"Name": Property to return the name of the folder.
"ParentFolder": Property to return the "Folder" object of the parent folder.
"Path": Property to return the path string of the folder.
"ShortName": Property to return the name of the folder in 8.3 format.
"ShortPath": Property to return the path string of the folder in 8.3 format.
"Size": Property to return the size of the folder in bytes.
"SubFolders": Property to return a read-only collection of "Folder" objects representing all the sub folders in the path string of the folder.
"Copy(destination[,true|false])": Method to copy everything in the folder to the specified destination. The optional
argument [true|false] specifies that the copy operation will override any existing files and sub folders.
"Delete([true|false])": Method to delete everything in the folder. The optional [true|false] argument specifies
that the delete operation will delete the read-only files and sub folders.
"Move(destination)": Method to move the folder to the specified destination.
"CreateTextFile(filename[,true|false[,true|false]])": Method to create a text file in the folder.
The first optional [true|false] argument specifies that the new file override existing file, and the
second one specifies that the file will be created in Unicode. I am not sure in what encoding.
The following ASP shows how the Folder object can be used to list all the information
about a folder:
<script language="vbscript" runat="server">
' folder_test.asp
' Copyright (c) 1999 by Dr. Herong Yang
' This program shows how to browse the directory tree of a drive.
'
response.write("<html><body>")
response.write("<b>Tests on the folder tree</b>:<br/>")
' Creating a FileSystemObject object
set fs = CreateObject("Scripting.FileSystemObject")
' Getting a specific folder
set f = fs.GetFolder("c:\inetpub\wwwroot")
call displayFolderInfo(f)
sub displayFolderInfo(f)
response.write("Path = " & f.Path & "<br/>")
response.write("Name = " & f.Name & "<br/>")
response.write("Short Name = " & f.ShortName & "<br/>")
response.write("Short Path = " & f.ShortPath & "<br/>")
response.write("Drive = " & f.Drive & "<br/>")
response.write("Size = " & f.Size & "<br/>")
response.write("Attributes = " & f.Attributes & "<br/>")
response.write("Date created = " & f.DateCreated & "<br/>")
response.write("Is Root Folder = " & f.IsRootFolder & "<br/>")
set l = f.SubFolders
for each sf in l
response.write("Sub Folder = " & sf.Name & "<br/>")
next
set l = f.Files
for each sf in l
response.write("File = " & sf.Name & "<br/>")
next
end sub
response.write("</body></html>")
</script>
Output:
Tests on the folder tree:
Path = C:\Inetpub\wwwroot
Name = wwwroot
Short Name = wwwroot
Short Path = C:\inetpub\wwwroot
Drive = c:
Size = 439424
Attributes = 48
Date created = 4/19/2000 3:16:15 PM
Is Root Folder = False
Sub Folder = asp
Sub Folder = aspnet_client
Sub Folder = images
Sub Folder = list
Sub Folder = _private
Sub Folder = _vti_cnf
Sub Folder = _vti_log
Sub Folder = _vti_pvt
Sub Folder = _vti_script
Sub Folder = _vti_txt
File = default.asp
File = default.htm
File = hello.asp
File = hello.html
File = help.gif
File = iisstart.asp
File = localstart.asp
File = mmc.gif
File = pagerror.gif
File = postinfo.html
File = print.gif
File = warning.gif
File = web.gif
File = win2000.gif
File = _vti_inf.html
