JVM Tutorials - Herong's Tutorial Examples - v5.14, by Herong Yang
Jasmin Example - Calculator.j
This section provides a tutorial example on how to write a simple calculator in Jasmin: Calculator.j.
Now let's try to a more complex Jasmin program: Calculator.j.
1. Requirements - Calculator.j should take 3 arguments: <number1> <operator> <number2>, calculate and print the result.
2. Java Version: Calculator.java - We should write the Java version first. It helps us to define the program flow structure.
/* Calculator.java
* Copyright (c) HerongYang.com. All Rights Reserved.
*/
public class Calculator {
public static void main(String[] args) {
if (args.length != 3) {
System.out.println("Error: Invalid number of arguments.");
System.out.println("Usage: java Calculator <number> <operator> <number>");
return;
}
try {
double x = Double.parseDouble(args[0]);
String op = args[1];
double y = Double.parseDouble(args[2]);
double r = 0;
switch (op) {
case "+":
r = x + y;
break;
case "-":
r = x - y;
break;
case "*":
r = x * y;
break;
case "/":
if (y == 0) {
System.out.println("Error: Division by zero is not allowed.");
return;
}
r = x / y;
break;
default:
System.out.println("Error: Invalid operator. Use +, -, *, or /.");
return;
}
System.out.println(r);
} catch (NumberFormatException e) {
System.out.println("Error: Please provide valid numeric values.");
}
}
}
3. Review the Bytecode with "javap" - Compile the Calculator.java and view the bytecode with "javap -c" command.
herong> javac Calculator.java
herong> javap -c Calculator.class
Compiled from "Calculator.java"
public class Calculator {
public Calculator();
Code:
0: aload_0
1: invokespecial #1 // Method java/lang/Object."<init>":()V
4: return
public static void main(java.lang.String[]);
Code:
0: aload_0
1: arraylength
2: iconst_3
3: if_icmpeq 23
6: getstatic #7 // Field java/lang/System.out:Ljava/io/...
9: ldc #13 // String Error: Invalid number of argu...
11: invokevirtual #15 // Method java/io/PrintStream.println:(...
14: getstatic #7 // Field java/lang/System.out:Ljava/io/...
17: ldc #21 // String Usage: java Calculator <nu...
19: invokevirtual #15 // Method java/io/PrintStream.println:(...
22: return
23: aload_0
24: iconst_0
25: aaload
26: invokestatic #23 // Method java/lang/Double.parseDouble:...
29: dstore_1
30: aload_0
31: iconst_1
32: aaload
33: astore_3
34: aload_0
35: iconst_2
36: aaload
37: invokestatic #23 // Method java/lang/Double.parseDouble:...
40: dstore 4
42: dconst_0
43: dstore 6
45: aload_3
46: astore 8
48: iconst_m1
49: istore 9
51: aload 8
53: invokevirtual #29 // Method java/lang/String.hashCode:()I
56: tableswitch { // 42 to 47
42: 128
43: 96
44: 157
45: 112
46: 157
47: 144
default: 157
}
96: aload 8
98: ldc #35 // String +
100: invokevirtual #37 // Method java/lang/String.equals:(Ljav...
103: ifeq 157
106: iconst_0
107: istore 9
109: goto 157
112: aload 8
114: ldc #41 // String -
116: invokevirtual #37 // Method java/lang/String.equals:(Ljav...
119: ifeq 157
122: iconst_1
123: istore 9
125: goto 157
128: aload 8
130: ldc #43 // String *
132: invokevirtual #37 // Method java/lang/String.equals:(Lja...
135: ifeq 157
138: iconst_2
139: istore 9
141: goto 157
144: aload 8
146: ldc #45 // String /
148: invokevirtual #37 // Method java/lang/String.equals:(Ljav...
151: ifeq 157
154: iconst_3
155: istore 9
157: iload 9
159: tableswitch { // 0 to 3
0: 188
1: 197
2: 206
3: 215
default: 240
}
188: dload_1
189: dload 4
191: dadd
192: dstore 6
194: goto 249
197: dload_1
198: dload 4
200: dsub
201: dstore 6
203: goto 249
206: dload_1
207: dload 4
209: dmul
210: dstore 6
212: goto 249
215: dload 4
217: dconst_0
218: dcmpl
219: ifne 231
222: getstatic #7 // Field java/lang/System.out:Ljava/io/...
225: ldc #47 // String Error: Division by zero is no...
227: invokevirtual #15 // Method java/io/PrintStream.println:(...
230: return
231: dload_1
232: dload 4
234: ddiv
235: dstore 6
237: goto 249
240: getstatic #7 // Field java/lang/System.out:Ljava/io/...
243: ldc #49 // String Error: Invalid operator. Use ...
245: invokevirtual #15 // Method java/io/PrintStream.println:(...
248: return
249: getstatic #7 // Field java/lang/System.out:Ljava/io/...
252: dload 6
254: invokevirtual #51 // Method java/io/PrintStream.println:(...
257: goto 269
260: astore_1
261: getstatic #7 // Field java/lang/System.out:Ljava/io/...
264: ldc #56 // String Error: Please provide valid n...
266: invokevirtual #15 // Method java/io/PrintStream.println:(...
269: return
Exception table:
from to target type
23 230 260 Class java/lang/NumberFormatException
231 248 260 Class java/lang/NumberFormatException
249 257 260 Class java/lang/NumberFormatException
}
5. Jasmin version: Calculator.j - Now write the Jasmin version by following the "javap" output.
; Calculator.j
; Copyright (c) HerongYang.com. All Rights Reserved.
;
.class public Calculator
.super java/lang/Object
.method public <init>()V ; the default constructor
aload_0
invokespecial java/lang/Object/<init>()V
return
.end method
.method public static main([Ljava/lang/String;)V
.limit stack 4 ; 4 slots needed x(2), y(2)
.limit locals 8 ; 8 slots needed args, x(2), op, y(2), r(2)
; define a try-catch block
.catch java/lang/NumberFormatException from TryStart to TryEnd using CatchClause
aload_0 ; load address from variable 0, the first argument: args
arraylength ; get args.length
bipush 3 ; load int 3
if_icmpeq TryStart ; skip error messages, if args.length == 3
; print out error messages
getstatic java/lang/System/out Ljava/io/PrintStream;
ldc "Error: Invalid number of arguments."
invokevirtual java/io/PrintStream/println(Ljava/lang/String;)V
getstatic java/lang/System/out Ljava/io/PrintStream;
ldc "Usage: java Calculator <number> <operator> <number>"
invokevirtual java/io/PrintStream/println(Ljava/lang/String;)V
return
TryStart:
; parse the args[0] as a double value
aload_0 ; load args address
iconst_0 ; load index 0
aaload ; load args[0]
invokestatic java/lang/Double/parseDouble(Ljava/lang/String;)D
dstore_1 ; store it in variable 1 and 2 as x, double requires 2 slots
aload_0 ; load args address
iconst_1 ; load index 1
aaload ; load args[1]
iconst_0 ; load index 0
invokevirtual java/lang/String/charAt(I)C
istore_3 ; store it in variable 3 as op
aload_0 ; load args address
iconst_2 ; load index 2
aaload ; load args[2]
invokestatic java/lang/Double/parseDouble(Ljava/lang/String;)D
dstore 4 ; store it in variable 4 and 5 as y, double requires 2 slots
TryEnd:
iload_3 ; load op from variable 3
lookupswitch
42: DoMul ; '*' is ASCII 42
43: DoAdd ; '+' is ASCII 43
45: DoSub ; '-' is ASCII 45
47: DoDiv ; '/' is ASCII 47
default: InvalidOp
DoAdd: ; load x and y, perform addition, store r
dload_1
dload 4
dadd
dstore 6
goto PrintResult
DoSub: ; load x and y, perform subtraction, store r
dload_1
dload 4
dsub
dstore 6
goto PrintResult
DoMul: ; load x and y, perform multiplication, store r
dload_1
dload 4
dmul
dstore 6
goto PrintResult
DoDiv: ; load y, make sure it's not 0.0
dload 4 ; load y
dconst_0 ; load 0.0
dcmpl ; compare and generate -1, 0 or 1
ifeq DivZero ; go to error handling, if 0
dload_1 ; load x and y, perform division, store r
dload 4
ddiv
dstore 6
goto PrintResult
PrintResult:
getstatic java/lang/System/out Ljava/io/PrintStream;
dload 6
invokevirtual java/io/PrintStream/println(D)V
return
InvalidOp:
getstatic java/lang/System/out Ljava/io/PrintStream;
ldc "Error: Invalid operator. Use +, -, *, or /."
invokevirtual java/io/PrintStream/println(Ljava/lang/String;)V
return
DivZero:
getstatic java/lang/System/out Ljava/io/PrintStream;
ldc "Error: Division by zero is not allowed."
invokevirtual java/io/PrintStream/println(Ljava/lang/String;)V
return
CatchClause:
; When an exception hits, the exception object reference is pushed onto the stack.
; We pop it to clear the stack, then print our custom error.
pop
getstatic java/lang/System/out Ljava/io/PrintStream;
ldc "Error: Please provide valid numeric values."
invokevirtual java/io/PrintStream/println(Ljava/lang/String;)V
return
.end method
6. Test - Compile it with Jasmin and test it.
herong> java -jar jasmin-2.4/jasmin.jar Calculator.j Generated: Calculator.class herong> java Calculator 0.9999 + 0.0001 1.0 herong> java Calculator 0.9999 - 0.0001 0.9998 herong> java Calculator 0.9999 '*' 0.0001 9.999000000000001E-5 herong> java Calculator 0.9999 / 2 0.49995 herong> java Calculator 0.9999 2 Error: Invalid number of arguments. Usage: java Calculator <number> <operator> <number> herong> java Calculator 0.9999 / two Error: Please provide valid numeric values. herong> java Calculator 0.9999 % 2 Error: Invalid operator. Use +, -, *, or /. herong> java Calculator 0.9999 / 0 Error: Division by zero is not allowed.
Cool! Calculator.j seems to be working correctly.
7. Compare Bytecode - Now let's compare the bytecodes generated from Calculator.j (Jasmin version) with Calculator.java (Java version):
herong> java -jar jasmin-2.4/jasmin.jar Calculator.j Generated: Calculator.class herong> ls -l Calculator.class -rw-r--r-- 1 herong staff 943 Nov 10 20:54 Calculator.class herong> javac Calculator.java herong> ls Calculator.* -rw-r--r-- 1 herong staff 1375 Nov 10 21:06 Calculator.class herong> java Calculator 1375 - 943 432.0 herong> java Calculator 432 / 1375 0.3141818181818182
The bytecode generated from the Jasmin version is about 31% smaller than the Java version, 943 vs. 1375 bytes, So if you re-write your Java program in Jasmin assembly, you can reduce your program's footprint on JVM by 31%.
Table of Contents
JVM (Java Virtual Machine) Specification
Java HotSpot VM - JVM by Oracle/Sun
java.lang.Runtime Class - The JVM Instance
java.lang.System Class - The Operating System
ClassLoader Class - Class Loaders
Class Class - Class Reflections
JVM Stack, Frame and Stack Overflow
Thread Testing Program and Result
CPU Impact of Multi-Thread Applications
I/O Impact of Multi-Thread Applications
Micro Benchmark Runner and JVM Options
Micro Benchmark Tests on "int" Operations
Micro Benchmark Tests on "long" Operations
Micro Benchmark Tests in JIT Compilation Mode
Micro Benchmark Tests on "float" and "double" Operations
JRockit JVM 28.2.7 by Oracle Corporation
JVM Bytecode and Instruction Set
►JVM Assembler/Disassembler Tools
Compare HelloWorld.j with "javap" Output
►Jasmin Example - Calculator.j
JASM Example - Calculator.jasm
AsmTools/JASM Assembly Statements
AsmTools/JASM Example - Calculator.jasm
AsmTools/JASM Disassembler: "jdis"
AsmTools/JCOD Assembly File Format
AsmTools/JCOD Example - HelloWorld.jcod
AsmTools/JCOD Disassembler: "jdec"